home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD004b.dsk / HI-RES.METRONOME.bas < prev    next >
BASIC Source File  |  2003-06-12  |  3KB  |  96 lines
  1. 10  REM   HI-RES METRONOME
  2. 20  REM IF CTRL-C THEN TEXT
  3. 30  ONERR  GOTO 560
  4. 40  GOSUB 460: REM POKES
  5. 50  REM SET HIRES MODE, CLEAR   TEXT WINDOW, AND MOVE CURSORTO BOTTOM OF SCREEN
  6. 60  HGR : HOME : VTAB 21
  7. 70  REM PRINT TITLE,ETC.
  8. 80  INVERSE 
  9. 90  HTAB 12: PRINT "APPLE ][ METRONOME"
  10. 100  HTAB 12: PRINT "                  ": NORMAL 
  11. 110  HTAB 9: PRINT "PAD";: INVERSE : PRINT "DLE #0 CONTROLS TE";: NORMAL : PRINT "MPO"
  12. 120  HTAB 6: PRINT "PADDLE";: INVERSE : PRINT " #1  CONTROLS STEP";: NORMAL : PRINT " VALUE";
  13. 130  REM DRAW METRONOME
  14. 140  HCOLOR= 2
  15. 150  FOR X = 80 TO 200: HPLOT 140,40 TO X,159: NEXT 
  16. 160  REM X & Y ARE COORDINATES ATWHICH TO DRAW PENDULUM;SET  COLOR
  17. 170 X = 140:Y = 155: HCOLOR= 3
  18. 180  SCALE= 55
  19. 190  REM LEFT TO RIGHT;R IS ROT- ATION;STEP BY A FRACTION OF PADDLE(1)
  20. 200  FOR R = 185 TO 199  STEP  PDL(1)/50 +1
  21. 210  ROT= R
  22. 220  REM DRAW PENDULUM
  23. 230  XDRAW 1 AT X,Y
  24. 240  REM PAUSE
  25. 250  FOR T = 1 TO  PDL(0): NEXT 
  26. 260  REM ERASE PENDULUM
  27. 270  XDRAW 1 AT X,Y
  28. 280  NEXT 
  29. 290  REM TONE
  30. 300  XDRAW 1 AT X,Y: POKE 768,255: POKE 769,10: CALL 770: XDRAW 1 AT X,Y
  31. 310  REM LEFT TO RIGHT STEP      PADDLE(0)
  32. 320  FOR R = 199 TO 185  STEP  - PDL(1)/50 -1
  33. 330  ROT= R
  34. 340  REM DRAW PENDULUM
  35. 350  XDRAW 1 AT X,Y
  36. 360  REM PAUSE
  37. 370  FOR T = 1 TO  PDL(0): NEXT 
  38. 380  REM ERASE PENDULUM
  39. 390  XDRAW 1 AT X,Y
  40. 400  NEXT 
  41. 410  REM TONE
  42. 420  XDRAW 1 AT X,Y: POKE 768,255: POKE 769,10: CALL 770: XDRAW 1 AT X,Y
  43. 430  REM START OVER
  44. 440  GOTO 200
  45. 450  REM DATA FOR MACH.LANG.
  46. 460  DATA 173,48,192,136,208,5,206,1,3,240,9,202,208,245,174,0,3,76,2,3,96,1,0,4,0,4,4,0,252,29
  47. 470  REM POKE MACH.LANG.
  48. 480  FOR PKE = 770 TO 790
  49. 490  READ P: POKE PKE,P
  50. 500  NEXT 
  51. 510  FOR PKE = 7676 TO 7682
  52. 520  READ P: POKE PKE,P
  53. 530  NEXT : READ P: POKE 232,P: POKE 115,P: READ P: POKE 233,P: POKE 116,P
  54. 540  RETURN 
  55. 550  REM ONERR BRINGS US HERE
  56. 560  HOME : TEXT : END 
  57. 565  REM 
  58. 567  REM 
  59. 570  REM +-------------------+
  60. 580  REM : V A R I A B L E S :
  61. 590  REM :      -----        :
  62. 600  REM : P...POKE VALUES   :
  63. 610  REM : PKE.MEMORY LOC    :
  64. 620  REM : R..."ROT" SHAPE   :
  65. 630  REM : T...FOR/NEXT PAUSE:
  66. 640  REM : X...HORIZ. LOC.FOR:
  67. 650  REM :     SHAPE DRAW    :
  68. 660  REM : Y...VERT. LOC. FOR:
  69. 670  REM :     SHAPE DRAW    :
  70. 680  REM +-------------------+
  71. 690  REM 
  72. 700  REM   "HI-RES METRONOME"
  73. 710  REM 
  74. 720  REM       BY JIM GANZ
  75. 730  REM 
  76. 740  REM         * * * *
  77. 750  REM 
  78. 760  REM    AN UNCALIBRATED
  79. 770  REM    METRONOME.
  80. 780  REM 
  81. 790  REM REQUIREMENTS:
  82. 800  REM APPLESOFT ][ AND
  83. 810  REM HAND CONTROLLERS
  84. 820  REM 
  85. 830  REM         * * * *
  86. 831  REM 
  87. 832  REM        CLASSIFIED
  88. 833  REM     -PUBLIC  DOMAIN-
  89. 834  REM      NOVEMBER, 1981
  90. 840  REM 
  91. 850  REM PLEASE RETAIN LINES
  92. 860  REM 565-900
  93. 870  REM IN ALL COPIES.
  94. 880  REM        -THANK YOU!!
  95. 890  REM 
  96. 900  REM         * * * *